Strona Szoguna

Klasa HttpClient

Klasa ta opakowuje klasę WiFiClient i udostępnia metody pozwalające obsłużyć protokół http. Metody begin i end wskazują początek i koniec obsługi wywołania http. Metoda begin pobiera jako parametr adres, z którym należy nawiązać połączenie. Dodatkowo klasa posiada metodę addHeader dodającą nagłówek http, bezparametrową metody GET i POST pozwalające wysłać lub odebrać dane z serwera.

Kod układu sterującego diodą wygląda następująco:

#include <ESP8266WiFi.h>
#include <ESP8266WiFiMulti.h>
#include <ESP8266HTTPClient.h>

#include <WiFiClient.h>

ESP8266WiFiMulti WiFiMulti;

void setup() {
    WiFi.mode(WIFI_STA);
    WiFiMulti.addAP("<SSID>", "<Password>");
    pinMode(LED_BUILTIN, OUTPUT);
}

void loop() {
  if (WiFiMulti.run() != WL_CONNECTED) {
    delay(300);
    return;
  }
  WiFiClient client;
  HTTPClient http;

  if (http.begin(client, "http://<your-dns-name-or-ip>:5000/led")) {
    int httpCode = http.GET();

    String payload = http.getString();

    if (payload == "ON") {
      digitalWrite(LED_BUILTIN, LOW);
    } else {
      digitalWrite(LED_BUILTIN, HIGH);
    }
  }

  delay(300);
}

Natomiast układu reagującego na wciśnięcie przycisku:

#include <ESP8266WiFi.h>
#include <ESP8266WiFiMulti.h>
#include <ESP8266HTTPClient.h>

#include <WiFiClient.h>

ESP8266WiFiMulti WiFiMulti;
int prevButtonState = LOW;

void setup() {
  WiFi.mode(WIFI_STA);
  WiFiMulti.addAP("<SSID>", "<Password>");
  pinMode(0, INPUT_PULLUP);
}

void loop() {
  if (WiFiMulti.run() != WL_CONNECTED) {
    delay(300);
    return;
  }
  WiFiClient client;
  HTTPClient http;
  int readValue = digitalRead(0);
  if (readValue == LOW && prevButtonState == HIGH) {
    if (http.begin(client, "http://<your-dns-name-or-ip>:5000/button")) {
      http.addHeader("content-type", "application/json");
      int httpCode = http.POST("");
    }
  }
  prevButtonState = readValue;

  delay(300);
}

Układ sterujący diodą został po prostu podłączony do zasilania (przez programator w trybie UART). Układ reagujący na wciśnięcie przycisku został skonstruowany w sposób opisany w poprzednim artykule. Jak widać na nagraniu całość działa.

Rozwiązanie ma jednak swoje wady:

• Serwer nie weryfikuje czy urządzenie, które się z nim łączy jest tym za które się podaje
• Nawet gdyby serwer dokonywał weryfikacji, to transmisja jest nieszyfrowana, więc ktoś mógłby ją podsłuchać i wydobyć dane potrzebne do podszycia się
• Protokół http jest dość ciężki, na nagraniu wszystko wydaje się działać natychmiastowo, wynika to jednak tylko z faktu iż serwer znajduje się w tej samej sieci WiFi

Inne artykuły związane z Internetem rzeczy

Układ działa już dużo lepiej, zdarza się jednak że po naciśnięciu przycisku lampka nie wyłącza/ nie włącza się. Wynika to z faktu iż układ jest znacznie szybszy niż ludzki palec i pojedyncze wciśnięcie przycisku jest interpretowane jako ciąg wciśnięć.

Rozwiązaniem jest zmiana wykrywania stanu niskiego na wykrywanie zmiany stanu z niskiego na wysoki:

int ledState = LOW;
int prevButtonState = LOW;
void setup() {
   pinMode(0, INPUT_PULLUP);
   pinMode(LED_BUILTIN, OUTPUT);
}

void loop() {
    int readValue = digitalRead(0);
    if (readValue == LOW && prevButtonState == HIGH) {
        ledState = ledState == HIGH ? LOW : HIGH;
        digitalWrite(LED_BUILTIN, ledState);
    }
    prevButtonState = readValue;
}

Powyższy kod zredukował problem, nie usunął go jednak całkowicie. Winny temu jest tzw. bouncing. W trakcie wciskania elementy przycisku trą i odbijają się od siebie, co sprawia, że przepływ prądu jest przerywany i wznawiany.

Problem można rozwiązać sprzętowo: wstawiając kondensator wokół przycisku. W moim przypadku całkiem nie źle się sprawdził elektrolityczny kondensator 4,7 mikrofarada.

Problem można też rozwiązać programowo, program może sprawdzić czy kolejne przełączenie przycisku nastąpiło bezpośrednio po poprzednim przez wywołanie metody millis, która zwraca czas w milisekundach który upłynął od uruchomienia programu i sprawdzeniu czy od poprzedniej zmiany stanu minął określony przedział czasu.

int ledState = LOW;
int prevButtonState = LOW;
unsigned long lastDebounceTime = 0;
unsigned long debounceDelay = 100;

void setup() {
   pinMode(0, INPUT_PULLUP);
   pinMode(LED_BUILTIN, OUTPUT);
}

void loop() {
    int readValue = digitalRead(0);
    if (readValue == LOW && prevButtonState == HIGH) {
      if ((millis() - lastDebounceTime) > debounceDelay) {
        lastDebounceTime = millis();
        ledState = ledState == HIGH ? LOW : HIGH;
      }
    }
    digitalWrite(LED_BUILTIN, ledState);
    prevButtonState = readValue;
}

Czytelnikom chcącym dowiedzieć się czegoś więcej na temat bouncingu polecam film na kanale RS Elektronika

Inne artykuły związane z Internetem rzeczy

Uruchomienie programu

Aby móc uruchomić program na płytce potrzebny jest programator – urządzenie posiadające port szeregowy pracujący w napięciu 3.3V i prędkością 115.2kbps. Żaden ze standardowych portów w komputerze nie spełnia tych wymagań, W internecie można znaleźć opis jak wykorzystać Arduino jako adapter ale ja kupiłem gotowy układ.

Należy podpiąć układ do programatora, a programator do komputera. Trzeba się też upewnić czy programator jest poprawnie ustawiony. Mój posiada mały przełącznik który przełącza układ między trybami komunikacji i programowania. Inne programatory posiadają np regulację napięcia między 3.3 i 5 Volt – to wyższe usmaży nam płytkę.

Następnie należy otworzyć Arduino IDE, kliknąć „Tools > Port > Numer portu odpowiadający programatorowi”. Na liście może znajdować się wiele portów COM, w przypadku trudności z identyfikacją należy odłączać i podłączać programator – lista portów odświeża się przy otwarciu menu „Tools”.

Na koniec zostaje wgrać program przyciskiem upload (duża strzałka w prawo), podłączyć układ do zasilania i patrzeć jak działa.

Inne artykuły związane z Internetem rzeczy